(defun c:save_views( / data dat_id fname vlist)
(setq data (tblnext "view" T))
(cond ((not data) (princ "\nNo named views in this drawing."))
       ((not (setq fname (getfiled "Filename" "" "vw" 3))) ())
       ((not (setq dat_id (open fname "w")))
        (alert (strcat "Cannot open file " fname " for write"))
       )
       (T
        (princ ";AutoCAD saved views - don't modify this file!!!"
dat_id)
        (princ "\n'" dat_id)
        (while data
         (setq vlist (cons (cdr data) vlist)
               data (tblnext "view"))
        )
        (prin1 vlist dat_id)
        (close dat_id)
       )
)
(princ)
)
(defun c:restore_views( / fname data i stub)
(setq fname (getfiled "Filename" "" "vw" 2))
(cond ((not fname) ())
       ((= (setq data (load fname "error")) "error")
        (princ (strcat "\n" fname ": wrong file format."))
       )
       (T
        (setq i 0
              stub '((0 . "VIEW")(100 . "AcDbSymbolTableRecord")
                     (100 . "AcDbViewTableRecord")))
        (foreach x data
         (if (entmake (append stub x)) (setq i (1+ i)))
        )
        (mapcar 'princ (list "\n" i " view(s) created."))
       )
)
(princ)
)